選択ｾｯﾄを利用する

普段選択ｾｯﾄを利用しないのですが、何となくﾏｸﾛで操作できるものか
調べてみました。　無いんですよね、ｻﾝﾌﾟﾙが。

SelectionSetsｸﾗｽが存在しているのは判るのですが、どうやって取得
すれば良いのか全く不明だったのですが、こちらに記載されていました。
COE : Forums : CreateSelectionSet

どうやってこんなの調べるんだろう・・・。

ｻﾝﾌﾟﾙｺｰﾄﾞです。

'vba
Sub CATMain()
    '準備
    Dim PDoc As PartDocument: Set PDoc = CATIA.ActiveDocument
    Dim Pt As Part: Set Pt = PDoc.Part
    Dim Sel As Selection: Set Sel = PDoc.Selection
    
    '選択ｾｯﾄｺﾚｸｼｮﾝの取得
    Dim SelSets As SelectionSets '型指定してもｴﾗｰになりませんでした
    Set SelSets = PDoc.Product.GetItem("CATIAVBSelectionSetsImpl")
    
    '選択ｾｯﾄ作成
    Call SelSets.CreateSelectionSet("hoge")
    
    '指定した選択ｾｯﾄにｴﾚﾒﾝﾄ追加
    '事前に選択する事で可能です。試しにﾊﾟｰﾂﾎﾞﾃﾞｨを入れます。
    Sel.Add Pt.MainBody
    Call SelSets.AddCSOIntoSelectionSet("hoge")
    
    Stop '確認用
    
    '選択ｾｯﾄをﾘﾈｰﾑ
    Call SelSets.RenameSelectionSet("hoge", "piyo")
    
    '選択ｾｯﾄを利用し選択状態にする
    '動作確認の為、事前にｸﾘｱしておきます
    Sel.Clear
    Call SelSets.PutSelectionSetIntoCSO("piyo")
    
    '選択ｾｯﾄのﾘｽﾄを取得 - ｴﾗｰで使い方判らない
    Dim SSList As Variant
    'Call SelSets.GetListOfSelectionSet(SSList) 'NG
    
    '選択ｾｯﾄ削除
    '削除後も選択状態は保たれています
    Call SelSets.DeleteSelectionSet("piyo")
End Sub

個別の "SelectionSet" のようなｸﾗｽは存在していないようで、
選択ｾｯﾄ名とSelectionｸﾗｽを使っての利用になるようです。

既存の選択ｾｯﾄにｴﾚﾒﾝﾄを追加するAddCSOIntoSelectionSet関数は
存在しているのですが、"ｴﾚﾒﾝﾄを除去" に該当する関数が
無さそうです。

GetListOfSelectionSet関数は、Partﾌｧｲﾙ内の選択ｾｯﾄのﾘｽﾄを
取得する為の関数のようですが、ｴﾗｰになり使い方が判らなかったです。
選択ｾｯﾄを作成する際、重複する名前でもｴﾗｰにならなかった為、
事前にﾁｪｯｸする必要があるような気がするので、ﾘｽﾄを取得したかった
のですが・・・。ちょっと危険な香りがします。

同一の複数の要素を何度も選択するようなﾏｸﾛの場合、ﾙｰﾌﾟ内で
Selection.Addを使ってｸﾞﾘｸﾞﾘやらなきゃならないのですが、
一度選択ｾｯﾄを作ってしまえば、すっきりしたｺｰﾄﾞで書けそうな
予感です。
(でも選択ｾｯﾄは、手動の時の方が価値が高いと思いますが)

以下は、忘れちゃいそうなので個人的なﾒﾓです。
AutomationManual内の説明書きで略語がﾁﾗﾎﾗ出てくるのですが、
何の略語かわからない時が多いです。
・CSO → Current Set of Objects
・HSO → Highlighted Set of Objects
・COG → Center of Gravity