非常に個人的なPowerMillﾏｸﾛ用ﾗｲﾌﾞﾗﾘ

あまりに苦しいので、ﾗｲﾌﾞﾗﾘ的なものを作りました。
PowerMillのﾏｸﾛは、ﾏｸﾛの実行ﾌｧｲﾙ(.mac)以外に拡張子「.inc」に
することでﾗｲﾌﾞﾗﾘとして使用できるんです。(ｴﾗｲ!)

//pmill macro Kantoku_PowerMill_Library ver0.0.2
//kpl.inc
//r2017で開発

// **** ﾌｫﾙﾀﾞ ****
//指定した組み込みﾌｫﾙﾀﾞからｴﾝﾃｨﾃｨの存在するﾌｫﾙﾀﾞﾈｰﾑﾘｽﾄ取得
//param : DirName (string)
//param : Name (string)
//param : OptIsNew(bool) - 指定の名前のﾌｫﾙﾀﾞが既存にあった場合新作するか? 0_新作しない 1_新作
//param : OptIsAct(bool) - 実行後ﾌｫﾙﾀﾞをｱｸﾃｨﾌﾞにするか?  0_非ｱｸﾃｨﾌﾞ1_ｱｸﾃｨﾌﾞ
//return : Outstr(string) - 新たに出来たﾌｫﾙﾀﾞ名
function Create_Folder(string DirName , string Name , bool OptIsNew , bool OptIsAct , output string Outstr) {
	string fullname = $DirName + '\' + $Name
	string list Before = get_folders($DirName)
	
	if member($Before, $fullname) {
		if not OptIsNew {
			if OptIsAct {
				ACTIVATE FOLDER $fullname
			}
			return
		} else {
			call Get_UnOverlap_Name($fullname , $Before, $fullname)
		}
	}
	
	CREATE FOLDER $DirName ; 
	string list After = get_folders($DirName)
	string list lst= subtract($After, $Before)
	string autoname = $lst[0]
	$Outstr = basename($fullname)
	RENAME FOLDER $autoname  $Outstr
	if OptIsAct {
		ACTIVATE FOLDER $fullname
	}
}

//重複しない名前を取得
//param : Name(string) - 候補名
//param : Lst(string list) - 比較ﾘｽﾄ
//return : Outstr(string) - 重複の無い名前
function Get_UnOverlap_Name(string Name , string list Lst , output string Outstr) {
	string tmpname = $Name
	int cnt = 0
	bool fg = 0
	do {
		$fg = member($Lst, $tmpname) 
		if not $fg {
			break
		}
		$cnt = $cnt + 1
		$tmpname = $Name + '_' + String($cnt)
	} white 1
	$Outstr = $tmpname
}

// **** ｴﾝﾃｨﾃｨ ****

//指定した組み込みﾌｫﾙﾀﾞからｴﾝﾃｨﾃｨの存在するﾌｫﾙﾀﾞﾈｰﾑﾘｽﾄ取得
//param : DirName (string)
//param : Calculate(int) - 計算FG　-1以下_全て 0_未計算のみ 1以上_計算済のみ
//param : Leval (int) - ﾌｫﾙﾀﾞの階層　組み込みﾌｫﾙﾀﾞは1　指定無しは0以下
//param : RemoveLst(string list) - 除外するﾌｫﾙﾀﾞ名ﾘｽﾄ
//return : Outlst(string list)
function Get_Entitys_Dir(string Dirname , int Calculate , int Level , string list RemoveLst , output string list Outlst) {
	string list paths = {}
	call Get_Entitys_Path($Dirname , $Calculate , $Level , $paths ) 
	
	string list lst = {}
	string dirtxt = ''
	foreach itm in $paths  {
		$dirtxt = basename(dirname($itm ) ) 
		if not member($RemoveLst , $dirtxt) {
			int dmy = add_last($lst, $dirtxt)
		}
	}
	int dmy = remove_duplicates($lst)
	$Outlst = $lst
}

//指定した組み込みﾌｫﾙﾀﾞからﾍﾞｰｽﾈｰﾑﾘｽﾄ取得
//param : DirName (string)
//param : Calculate(int) - 計算FG　-1以下_全て 0_未計算のみ 1以上_計算済のみ
//param : Leval (int) - ﾌｫﾙﾀﾞの階層　組み込みﾌｫﾙﾀﾞは1　指定無しは0以下
//return : Outlst(string list)
function Get_Entitys_Base(string Dirname  , int Calculate , int Level  , output string list Outlst) {
	string list paths = {}
	call Get_Entitys_Path($Dirname , $Calculate , $Level , $paths ) 
	
	string list lst = {}
	string txt = ''
	foreach itm in $paths  {
		$txt = string(basename($itm))
		int dmy = add_last($lst, $txt )
	}
	$Outlst = $lst
}

//指定した組み込みﾌｫﾙﾀﾞからﾊﾟｽﾘｽﾄ取得
//param : DirName (string)
//param : Calculate(int) - 計算FG　-1以下_全て 0_未計算のみ 1以上_計算済のみ
//param : Leval (int) - ﾌｫﾙﾀﾞの階層　組み込みﾌｫﾙﾀﾞは1　指定無しは0以下
//return : Outlst(string list)
function Get_Entitys_Path(string Dirname , int Calculate , int Level , output string list Outlst) {
	string list ents = {}
	string ent = ''
	int cal = -1
	foreach itm in folder($Dirname)  {
		$ent = pathname($itm)
		if $Level > 0 {
			if size(tokens($ent, "\")) != $Level + 1 {
				continue
			}
		}
		if $Calculate > -1 {
			switch $itm.computed {
				case 0
					if Calculate > 0 {
						continue
					}
					break
				case 1
					if Calculate == 0 {
						continue
					}
					break
			}
		}
		int dmy = add_last($ents, $ent)
	}
	$Outlst = $ents
}

// **** その他 ****
//ﾘｽﾄから文字列
//param : Lst (string list)
//param : Delimiter (string)
//return : Outtxt(string)
function Lst_ToString(string list Lst , string Delimiter , output string Outtxt) {
	string txt = ''
	foreach itm in $Lst {
		$txt = $txt + $itm + $Delimiter
	}
	int lng = length($txt) - length($Delimiter)
	$Outtxt = substring($txt , 0 , $lng)
	return
}

//ﾀﾞﾝﾌﾟ
function Dump(string list Lst) {
	string txt = ''
	call Lst_ToString($Lst , crlf , $txt )
	print = $txt
}

//ﾀﾞｲｱﾛｸﾞ類ｵﾝ
function DialogOn() {
	DIALOGS MESSAGE ON
	DIALOGS ERROR ON
	ECHO ON DCPDEBUG TRACE COMMAND ACCEPT
}

//ﾀﾞｲｱﾛｸﾞ類ｵﾌ
function DialogOff() {
	DIALOGS MESSAGE OFF
	DIALOGS ERROR OFF
	ECHO OFF DCPDEBUG UNTRACE COMMAND ACCEPT
}

ver0.0.1 - 完成
ver0.0.2 - Get_Entitys_Dir関数に除外ﾘｽﾄ追加

ｴﾝﾃｨﾃｨの名前の重複が許されない為、先日のﾏｸﾛも何度も何度もﾘｽﾄを
取得しなくてはならない為、その辺中心に作っています。

これを利用するﾃｽﾄﾏｸﾛがこちら。

//pmill macro ｸｽﾞﾕﾆｯﾄﾃｽﾄ

function Main() {
	call DialogOff()
	
	// **** ｴﾝﾃｨﾃｨ ****
	string list lst = {}
	print = "**path**"
	call Get_Entitys_Path('Toolpath' , 1, 0, $lst ) 
	call Dump($Lst )
	call Get_Entitys_Path('Boundary' , 1 , 0 , $lst ) 
	call Dump($Lst )
	
	print = "**base**"
	call Get_Entitys_Path('Toolpath' , 1,0 , $lst ) 
	call Dump($Lst )
	call Get_Entitys_Base('Boundary' , 1 , 0 , $lst ) 
	call Dump($Lst )
	
	print = "**dir**"
	call Get_Entitys_Dir('Toolpath' , 1 , 0 , $lst ) 
	call Dump($Lst )
	call Get_Entitys_Dir('Boundary' , 1 , 2 , $lst ) 
	call Dump($Lst )
	
	//**** ﾌｫﾙﾀﾞ ****
	string Dirname = ''
	call Create_Folder('Toolpath' , 'Hoge' , 1 , 1 , $Dirname)
	print = $Dirname
	call Create_Folder('Toolpath' , 'Hoge' , 1 , 1 , $Dirname)
	print = $Dirname
	call Create_Folder('Boundary' , 'Hoge' , 1 , 1 , $Dirname)
	print = $Dirname
	call Create_Folder('Boundary' , 'Hoge' , 1 , 1 , $Dirname)
	print = $Dirname
	call Create_Folder('Tool' , 'Hoge' , 1 , 1 , $Dirname)
	print = $Dirname
	call Create_Folder('Tool' , 'Hoge' , 1 , 1 , $Dirname)
	print = $Dirname
	
	call DialogOn()
}

include kpl.inc

最後に記載した

　･･･
include kpl.inc

で読み込んでます。最初じゃなくても大丈夫なんです。(ｴﾗｲ)
(最初だとｴﾗｰﾒｯｾｰｼﾞに表示された行がずれちゃうんです)

国内だとPowerMillﾕｰｻﾞｰ少なそうだから、使う人いないだろうなぁ
(日本語のﾌｫｰﾗﾑ作って欲しい･･･)