PowerMillﾏｸﾛのﾀﾞｲｱﾛｸﾞ類

前回は、結局ﾏﾆｭｱﾙに記載されていた関数のみでした。
今回こそは･･･、と思ったのですが、調べると今回も殆どがﾏﾆｭｱﾙ
記載のものです。

PowerMillのﾏｸﾛで処理した際、ﾏｸﾛﾕｰｻﾞｰに何らかのﾒｯｾｰｼﾞや選択を促す
ﾀﾞｲｱﾛｸﾞ類の覚書です。

〇ｴｺｰｺﾏﾝﾄﾞ
どちらかと言うと、開発者用です。
VBAのｲﾐﾃﾞｨｴｲﾄｳｨﾝﾄﾞｳと同等なｴｺｰｺﾏﾝﾄﾞへの出力です。
ｱｸﾃｨﾌﾞな工具名の出力です。

function main() {
	print = tool.name
}

〇message ～
OKﾎﾞﾀﾝのみのﾀﾞｲｱﾛｸﾞです。

function main() {
	message info tool.name
	message warn tool.name
	message error tool.name
}

〇INFOBOX
これはﾏﾆｭｱﾙに記載されていないです。
ﾎﾟｽﾄ処理やCADﾃﾞｰﾀをｲﾝﾎﾟｰﾄした際に現れるﾀﾞｲｱﾛｸﾞのようです。
messageﾀﾞｲｱﾛｸﾞより表現豊かで、これは表示されてもﾏｸﾛの実行が
止まりませんでした。又、これはﾏｸﾛから閉じる事も可能でした。

function main() {
	INFOBOX NEW "info box test"

	string txt = "HEADING STYLE : " + tool.name + crlf + crlf
	INFOBOX STYLE "HEADING"
	INFOBOX APPEND $txt

	$txt = "NORMAL STYLE : " + tool.name + crlf + crlf
	INFOBOX STYLE "NORMAL"
	INFOBOX APPEND  $txt

	$txt = "WARNING STYLE : " + to_xml(entity('Tool', tool.name))
	INFOBOX STYLE "WARNING"
	INFOBOX APPEND  $txt

	WAIT 3.0
	INFOBOX CLOSE
}

"WARNING STYLE : "の横のto_xml関数もﾏﾆｭｱﾙの記載が無く、ﾊﾟﾗﾒｰﾀをXMLﾌｫｰﾏｯﾄで
出力するようです。
WAIT関数もﾏﾆｭｱﾙの記載がありません。単位は秒のようです。
こちらのｻﾝﾌﾟﾙの方がｲﾛｲﾛと表現されています。
Delcam User Forum • View topic - Can you do images in a message box popup?

〇QUERY
'はい' 'いいえ' ﾎﾞﾀﾝを持つﾀﾞｲｱﾛｸﾞです。

function main() {
	bool yn = 0
	string msg = ''
	$yn = QUERY 'このﾌﾞﾛｸﾞの記述は、信用出来ない?'
	if $yn {
		$msg = 'その通り!'
	} else {
		$msg = 'よく考えよう!'
	}
	message warn $msg
}

〇input
単純な入力用ﾀﾞｲｱﾛｸﾞです。
事前に受け取る変数に値を入力しておくと、ﾃﾞﾌｫﾙﾄで設定されるようです。
(古いﾊﾞｰｼﾞｮﾝでは出来なかったような･･･)

function main() {
	int num = 23
	$num = input "何歳(数字で入力)"
	bool err = 0
	$err = error num
	string msg = ''
	if $err {
		$msg = '数字入力だって!!'
	} else {
		$msg = '多分、' + $num + '歳'
	}
	message warn $msg
}

上記のｺｰﾄﾞで文字を入力すると、通常は都合が悪く(int型に文字を代入)
ｴﾗｰになるべきなのですが、PowerMillのﾏｸﾛでは '0' が代入されてしまいます。
PowerMillのﾏｸﾛでは例外処理が出来ないのですが、inputに関しては
上記のｺｰﾄﾞの方法でｴﾗｰを拾えるようです。

〇input entity ～
指定した組み込みﾌｫﾙﾀﾞ内のｴﾝﾃｨﾃｨを選択肢としたｾﾚｸﾄﾎﾞｯｸｽです。
inputでは、ﾏｸﾛﾕｰｻﾞｰの入力ﾐｽに対してのﾁｪｯｸｺｰﾄﾞを用意する必要が
あると思いますが、こちらはその手間が省けるため、ﾏｸﾛの開発者・ﾕｰｻﾞｰの
負担が軽減できます。
事前に受け取る変数内に値を入れておけば、ﾃﾞﾌｫﾙﾄ値として表示されました。

function main() {
	string msg = "ｱｸﾃｨﾌﾞにする工具を選んでください" + crlf + "現在は " + tool.name
	string toolname = tool.name
	$toolname = input entity tool $msg
	activate tool $toolname
	message warn $toolname + " をｱｸﾃｨﾌﾞﾂｰﾙにしました"
}

上記ｺｰﾄﾞでは '工具ﾌｫﾙﾀﾞ' から工具を選択させるようにしています。

〇input entity multiple ～
input entity ～ は、ﾌﾟﾙﾀﾞｳﾝされたﾘｽﾄから1個しか選択出来ませんが、
こちらは複数選択が可能です。
事前に受け取る変数内に値を入れておいても、ﾃﾞﾌｫﾙﾄでﾁｪｯｸが入った
状態にはなりませんでした。

function main() {
	string msg = "ﾊﾞｯｸｸﾞﾗﾝﾄﾞで計算させるﾂｰﾙﾊﾟｽを選択してください" 
	entity list paths = input entity multiple toolpath $msg
	foreach path in $paths {
		INVALIDATE TOOLPATH $path.name
		EDIT TOOLPATH $path.name QUEUE
	}
	message info size($paths) + "個をﾊﾞｯｸｸﾞﾗﾝﾄﾞで計算登録しました"
}

上記のｺｰﾄﾞは、既に存在しているﾂｰﾙﾊﾟｽをﾌﾟﾙﾀﾞｳﾝﾘｽﾄし、選択されたﾂｰﾙﾊﾟｽを
ﾊﾞｯｸｸﾞﾗﾝﾄﾞ計算に投げるｺｰﾄﾞです。(計算済みのものも強制的に計算させます)

〇input choice
input entity multiple ～は組み込みﾌｫﾙﾀﾞ内の全てのｴﾝﾃｨﾃｨが表示されて
しまいます。上記のｺｰﾄﾞの場合であれば、未計算のﾂｰﾙﾊﾟｽだけを選択肢
したいところです。　こちらは事前に処理しておいたﾘｽﾄを選択肢として
おくことが可能です。　ﾘｽﾄの一番最初のものがﾃﾞﾌｫﾙﾄ値となるようです。
戻り値はﾘｽﾄのｲﾝﾃﾞｯｸｽです。

function main() {
	string list paths = extract(filter(folder('toolpath'), 'Computed == 0'), 'Name') 
	string msg = "ﾊﾞｯｸｸﾞﾗﾝﾄﾞで計算させるﾂｰﾙﾊﾟｽを選択してください" 
	int idx = input choice $paths $msg
	string cmd = "EDIT TOOLPATH " + $paths[$idx] +" QUEUE"
	docommand $cmd
	message info $paths[$idx]  + "をﾊﾞｯｸｸﾞﾗﾝﾄﾞで計算登録しました"
}

上記のｺｰﾄﾞは、先日のfilter・extract関数で事前に未計算のﾂｰﾙﾊﾟｽのみを
探し出し、ﾌﾟﾙﾀﾞｳﾝﾘｽﾄとして表示させます。

残念なのは、複数選択が出来ない事です。

ﾌｫｰﾗﾑを見ても

//これはNGです
・・・
string list paths = extract(filter(folder('toolpath'), 'Computed == 0'), 'Name') 
string msg = "ﾊﾞｯｸｸﾞﾗﾝﾄﾞで計算させるﾂｰﾙﾊﾟｽを選択してください" 
int idx = input choice multiple $paths $msg
・・・

の様に、ﾘｽﾄの複数選択したいけど出来ないの?　のような記載はありますが
どうも出来ないようです。
代案としては、どれか一つ組み込みﾌｫﾙﾀﾞを犠牲にして･･･と言う感じの
ｺｰﾄﾞに僕はしてみましたけど。