選択面の抽出

「抽出を行いたいが、選択面のみにならずに全体の面になってしまう」
と、ご相談を頂きました。

面の選択の際のﾌｨﾙﾀｰの問題かと思ったのですが、どうやら違うようです。
こちらで確認した所、これであれば選択面のみの抽出が出来ています。

'vba
Sub CATMain()
    'ﾄﾞｷｭﾒﾝﾄ等
    Dim doc As PartDocument
    Set doc = CATIA.ActiveDocument
    
    Dim pt As part
    Set pt = doc.part
    
    '選択
    Dim msg As String
    msg = "面選択"
    
    Dim filter As Variant
    filter = Array("Face")
    
    Dim sel As Variant ' Selection
    Set sel = doc.Selection
    Select Case sel.SelectElement2(filter, msg, False)
        Case "Cancel", "Undo", "Redo"
            Exit Sub
    End Select
    
    'ﾘﾌｧﾚﾝｽ取得
    Dim selectFace As AnyObject
    Set selectFace = sel.Item(1).Reference
    
    '抽出
    Dim face As AnyObject
    Set face = InitExtract(pt, selectFace)
    
    '形状ｾｯﾄ作成・挿入
    Dim hb As HybridBody
    Set hb = pt.hybridBodies.Add()
    
    hb.AppendHybridShape face
    
    MsgBox "Done"
End Sub

'抽出
Private Function InitExtract(ByVal pt As part, ByVal ref As Reference) _
                    As HybridShapeExtract
    Dim fact As HybridShapeFactory
    Set fact = pt.HybridShapeFactory
    
    Dim hybridShapeExtract1 As HybridShapeExtract
    Set hybridShapeExtract1 = fact.AddNewExtract(ref)
    
    hybridShapeExtract1.PropagationType = 3
    hybridShapeExtract1.ComplementaryExtract = False
    hybridShapeExtract1.IsFederated = False
    
    pt.UpdateObject hybridShapeExtract1
    Set InitExtract = hybridShapeExtract1
End Function

今回はSelectionからReferenceを取得してそのまま抽出する際の
Referenceとして使えましたが、場合によってはBrapﾈｰﾑから
Referenceを取得しなければならない場合もあるかも知れません。

「ｻﾌﾞﾂﾘｰ」ｺﾏﾝﾄﾞ

ﾏｸﾛで「ｻﾌﾞﾂﾘｰを開く」を行いたい　と御質問を頂きました。
結論を先に書くと出来なさそうです。が、その他調べた事を覚書しておきます。

今まで利用した事が無かったのですが、ﾒﾆｭｰの「表示」内に「ｻﾌﾞﾂﾘｰ」が
あるのを知りませんでした。

試した所、ちょっと不思議な感じがしました。

CATIAを起動し新たにPartを作成した状態では、こんな感じでｸﾞﾚｰｱｳﾄしてます。

これを利用する為には、一度ｺﾝﾃｷｽﾄﾒﾆｭｰの「ｻﾌﾞﾂﾘｰを開く」を実行すると
ﾁｪｯｸが入った状態で利用できます。

ｸﾘｯｸするとﾁｪｯｸが外れ、全てのｻﾌﾞﾂﾘｰｳｨﾝﾄﾞｳが消えます。

続いて新たにPartを作ります。
最初は利用できない状態ですが、一度ｺﾝﾃｷｽﾄﾒﾆｭｰの「ｻﾌﾞﾂﾘｰを開く」を実行します。
ここでﾒﾆｭｰからではなく、ｻﾌﾞﾂﾘｰｳｨﾝﾄﾞｳの×印をクリックし閉じます。

ここでﾒﾆｭｰを見ると、ｸﾞﾚｰｱｳﾄしてます。

先程とは状態が異なります。

ｻﾌﾞﾂﾘｰｳｨﾝﾄﾞｳの×印をクリックした場合は、実際にｳｨﾝﾄﾞｳを閉じていて
ﾒﾆｭｰの「ｻﾌﾞﾂﾘｰ」はｻﾌﾞﾂﾘｰｳｨﾝﾄﾞｳ全てを表示/非表示操作しているのだろう
と思われます。
（最初とX印で閉じた場合、表示/非表示に関わらずｻﾌﾞﾂﾘｰｳｨﾝﾄﾞｳが無い為
　ｺﾏﾝﾄﾞ自体が利用できない）

こんな制限付きの「ｻﾌﾞﾂﾘｰ」ｺﾏﾝﾄﾞであれば、こちらで利用可能です。

 '日本語
 CATIA.StartCommand ("ｻﾌﾞﾂﾘｰ")
 '英語
 CATIA.StartCommand ("Sub-Trees")

但し、ｻﾌﾞﾂﾘｰｳｨﾝﾄﾞｳが開いていても、CATIA.Windows.Countは変化無く
実際に開かれているのか？開かれていないのか？　はﾏｸﾛで判断する事も
難しそうです。（WinAPIでｺﾞﾘｺﾞﾘなら出来そうですが）

この「ｻﾌﾞﾂﾘｰ」ｺﾏﾝﾄﾞの存在に気が付いたのは、「表示」-「ｺﾏﾝﾄﾞﾘｽﾄ」です。

恐らくﾗｲｾﾝｽに関係無く、ｱｸﾃｨﾌﾞなﾜｰｸﾍﾞﾝﾁで利用可能なｺﾏﾝﾄﾞのﾘｽﾄを
表示してくれます。
ここで表示されるものであれば StartCommand で利用可能だと思います。

StartCommand は起動している言語に依存していますが、こちらに記載した
コマンドIDを利用すれば、言語依存しないﾏｸﾛが作れます。
コマンドID - C#ATIA

但し、今回の「ｻﾌﾞﾂﾘｰ」ｺﾏﾝﾄﾞについては、GrabCADにUpしたﾘｽﾄには
入ってませんでした･･･。

子ｳｨﾝﾄﾞｳの整列ｽﾀｲﾙ

御質問頂いた際、正直何のことかわかりませんでした。
が、調べたら理解できました。（最初はﾊﾟﾀｰﾝの何か? かと思いました）

要は、ここの表示の切り替えをﾏｸﾛで行いたいと言う事ですよね？

'CatArrangeStyleﾃｽﾄ
Sub CATMain()

    Call CATIA.Windows.Arrange(CatArrangeStyle.catArrangeCascade)
    CATIA.RefreshDisplay = True
    MsgBox "CatArrangeStyle - catArrangeCascade"
    
    Call CATIA.Windows.Arrange(CatArrangeStyle.catArrangeTiledHorizontal)
    CATIA.RefreshDisplay = True
    MsgBox "CatArrangeStyle - catArrangeTiledHorizontal"
        
    Call CATIA.Windows.Arrange(CatArrangeStyle.catArrangeTiledVertical)
    CATIA.RefreshDisplay = True
    MsgBox "CatArrangeStyle - catArrangeTiledVertical"

End Sub

3つのｽﾀｲﾙを順番に変更します。最小化しているｳｨﾝﾄﾞｳは影響無いようです。
又、環境や使用方法次第ですが、RefreshDisplayを入れておかないと
ｽﾀｲﾙの変更が間に合わない場合があるかもしれません。
（こちらで試した際、入れないと半分ぐらいしか表示しない状態で
　　MsgBoxが出現しました）

ﾃﾞｰﾀﾑ化された要素の入っている形状ｾｯﾄの取得

”ﾏｸﾛがPCによって動くものと動かないものがある”と相談を頂きました。
状況が良くわからないので、完全な答えには辿り着けない可能性も有りますが。。。

点を選択後、点の含まれている形状ｾｯﾄの取得部分が問題のようです。

まず、こんなﾃﾞｰﾀを用意しました。

点1は通常の状態で、点2はﾃﾞｰﾀﾑ化されています。

続いてこんなﾏｸﾛを作りました。

'catvba
Sub CATMain()
    Dim doc As PartDocument
    Set doc = CATIA.ActiveDocument
    
    Dim sel As Variant ' Selection
    Set sel = doc.Selection
    
    '選択
    Dim msg As String
    msg = "点を選択"
    
    Dim filter As Variant
    filter = Array("Point")
    
    sel.Clear
    Select Case sel.SelectElement2(filter, msg, False)
        Case "Cancel", "Undo", "Redo"
            Exit Sub
    End Select
    
    '選択要素の取得
    Dim point As AnyObject
    Set point = sel.Item(1).value
    
    '結果
    Debug.Print "********"
    Debug.Print "point typename : ", TypeName(point)
    Debug.Print "point.Parent typename : ", TypeName(point.Parent)
    Debug.Print "point.Parent.Parent typename : ", TypeName(point.Parent.Parent)
    Debug.Print "point.Thickness.Parent.Parent typename : ", TypeName(point.Thickness.Parent.Parent)
End Sub

点を選択し、Parentのｵﾌﾞｼﾞｪｸﾄﾀｲﾌﾟをｲﾐﾃﾞｨｴｲﾄｳｨﾝﾄﾞｳに表示します。
もう答えは書いているのですが・・・。

GSD要素がﾃﾞｰﾀﾑ化されている場合とされていない場合では、画面上や手動操作では
大きな違いを感じませんが、ﾏｸﾛではかなりの違いが有ります。

このﾏｸﾛで点1を選択した際の結果はこちら

********
point typename :            HybridShapePointOnPlane
point.Parent typename :     HybridShapes
point.Parent.Parent typename :            HybridBody
point.Thickness.Parent.Parent typename :  HybridBody

質問者さんのｺｰﾄﾞでは、"point.Parent.Parent" となっており、HybridBodyが
取得できています。

続いて点2を選択した際の結果はこちら

********
point typename :            HybridShapePointExplicit
point.Parent typename :     Parameters
point.Parent.Parent typename :            Part
point.Thickness.Parent.Parent typename :  HybridBody

"point.Parent.Parent" は、HybridBodyではなくPartになります。
そもそも point.Parent が、点1では HybridShapes なのに対し
点2では Parameters になります。

ﾃﾞｰﾀﾑ化されている・されていないを判断し処理を分けるのも
良いかもしれませんが、共通のﾌﾟﾛﾊﾟﾃｨ Thickness を利用すると
処理を分ける必要も無さそうです。

    Dim HybrBody As HybridBody
    Set HybrBody = point.Thickness.Parent.Parent

Thicknessﾌﾟﾛﾊﾟﾃｨ は　HybridShapeｵﾌﾞｼﾞｪｸﾄで実装されています。
以前から思うのですが、何故GSD要素に "厚み" が必要なのかな？
(ﾗｲｾﾝｽ無いのでわからないのですが ﾎﾞﾘｭｰﾑ?)

ﾌｧｲﾙを最小化でｵｰﾌﾟﾝしつつ、ｵｰﾌﾟﾝ前のｳｨﾝﾄﾞｳをｱｸﾃｨﾌﾞ化

「ﾊﾟﾜｰｺﾋﾟｰのPartﾌｧｲﾙを最小化で開きつつ、開く前のｱｸﾃｨﾌﾞな'ｳｨﾝﾄﾞｳをｱｸﾃｨﾌﾞ状態にする」
と言う内容のご相談を頂きました。

正直な所、どのような操作を想定されているのかが、把握できていない為
目的の状態になっていない可能性もありますが･･･

'vba
Sub CATMain()
    'ﾊﾟﾜｰｺﾋﾟｰﾌｧｲﾙ ﾊﾟｽ
    Dim PowerCopy_path As String
    PowerCopy_path = "C:\temp\powercopy_part.CATPart"
    
    'ﾊﾟﾜｰｺﾋﾟｰﾌｧｲﾙ ｵｰﾌﾟﾝ前に現在のｱｸﾃｨﾌﾞな
    'ｳｨﾝﾄﾞｳを取得
    Dim BeforeActWin As Window
    Set BeforeActWin = CATIA.ActiveWindow
    
    'ﾊﾟﾜｰｺﾋﾟｰﾌｧｲﾙ ｵｰﾌﾟﾝ
    Dim objPspDoc As PartDocument
    Set objPspDoc = CATIA.Documents.Open(PowerCopy_path)
    
    'ﾊﾟﾜｰｺﾋﾟｰﾌｧｲﾙ のｳｨﾝﾄﾞｳ
    Dim ActiveWin As Window
    'Set ActiveWin = CATIA.ActiveWindow
    Set ActiveWin = CATIA.Windows.Item(CATIA.Windows.count)
    
    '最小化
    ActiveWin.WindowState = catWindowStateMinimized
    
    '最初のｱｸﾃｨﾌﾞなｳｨﾝﾄﾞｳをｱｸﾃｨﾌﾞ
    BeforeActWin.Activate
    
    'ここで何かしらの処理
    Stop
    
    'ﾊﾟﾜｰｺﾋﾟｰﾌｧｲﾙ ｸﾛｰｽﾞ
    objPspDoc.Close
End Sub

・ﾌｧｲﾙをｵｰﾌﾟﾝする前に、現状のｱｸﾃｨﾌﾞｳｨﾝﾄﾞｳを取得しておきます。
　　（Set BeforeActWin = CATIA.ActiveWindow）
・ｳｨﾝﾄﾞｳの最小化はWindowStateﾌﾟﾛﾊﾟﾃｨで可能です。
　　（ActiveWin.WindowState = catWindowStateMinimized）

DrawingTextの中心座標

DrawingTextの中心座標を取得したい　との記載を見て思い付きで書きました。
Size of the textbox on a drawing - DASSAULT: CATIA products - Eng-Tips
最初に、”遅いよ”　って書いたんですけどね。

リトルクトゥルフさんがｱｯｻﾘ答えを書いてくれました。
・・・やっぱりレベルが違いすぎですね。

ｺｰﾄﾞが書かれていなかったので、作ってみたものの
リーダー（引き出し線）の削除でｴﾗｰになっちゃいます。

DrawingText.Leaders.Remove(0)

ん～　ｴﾗｰにはなるものの削除は出来てます。
仕方ないので On Error Resume Next　でｴﾗｰを回避するように
したのは良いのですが、すっきりしない。

探しまくってやっとCOEの記載を発見しました。
COE : Forums : Text box size
どうやっているのかな？　と思い見てみると
やっぱり On Error Resume Next　してます・・・。

僕だけじゃないようなので、すっきり。

VBA 言語環境による挙動の違い

先日のマクロですが、上手く動かないらしいのです。
draw with a catia all the Dual Geodesic Icosahedra - DASSAULT: CATIA products - Eng-Tips

原因が良くわからないのですが、CATIAのリリース違いが
影響するような程の最新の機能は使っていないはずです。

知識が無い為何とも言えないのですが、残る可能性は
言語の違いかと思っています。
マクロの内容的に、処理を速めるために正規表現を利用しているのですが
この辺がエンコードで上手く機能しないとか、ｴｸｽﾎﾟｰﾄしたVBAﾌｧｲﾙ
（~.bas,~cls）が、他の言語だと文字化けし機能しないとか･･･。

何か情報をお持ちの方、教えて頂けると助かります。