CATVBAの標準ﾓｼﾞｭｰﾙをﾏｸﾛで削除したい (希望)2

こちらの続きです。
CATVBAの標準ﾓｼﾞｭｰﾙをﾏｸﾛで削除したい (希望) - C#ATIA

imihitoさんから重要なｺﾒﾝﾄを頂いたので、早速試してみました。
試したｺｰﾄﾞはこちら

'vba
Sub MSAPC_Apc_Test()
    Dim oApc 'As Apc
    Set oApc = CreateObject("MSAPC.Apc")
    Dim oVBE 'As VBE
    Set oVBE = oApc.VBE 'ここでｴﾗｰ
End Sub

ﾀﾞﾒでした。　出てくるｴﾗｰは

VBA Initialization failed due to an invalid License Key

ﾗｲｾﾝｽが無いよ　って事ですかね?

Apcは取得できているようなので、ﾛｰｶﾙｳｨﾝﾄﾞｳを見ると

中身的には、ほぼ何も取得できていない感じが。
(Guidで0連発って・・・)

"MSAPC" で検索するとCOEのこれがﾋｯﾄしました。
COE : Forums : Macro Libraries problem on Win 7 64bit w/Office 2010

(Little Cthulhu氏 相変わらずｽｺﾞｲ)

WinXP 32bitで使っていたﾌﾟﾛｼﾞｪｸﾄﾌｧｲﾙを、Win7 64bitで取り込んだけど、
ﾏｸﾛが動かなかったんだよ。
　↓
新しいﾌﾟﾛｼﾞｪｸﾄﾌｧｲﾙを作成して、ｴｸｽﾎﾟｰﾄしたﾓｼﾞｭｰﾙ等をｲﾝﾎﾟｰﾄしなおせば
大丈夫。　Dave Frank氏のｺｰﾄﾞを参考にｴｸｽﾎﾟｰﾄｲﾝﾎﾟｰﾄを自動化する
ﾏｸﾛを作ってみたよ。
(念の為、ｴｸｽﾎﾟｰﾄはﾁﾏﾁﾏやる必要がありますが、ｲﾝﾎﾟｰﾄはﾌｧｲﾙをまとめて
VBEにD&Dすれば出来ます)

って書いてあるように解釈しました。

過去にもWinAPIで32bitでは動くけど、64bitでは上手く取得出来なかった
事が有ったので、これも64bitではﾀﾞﾒなのかな? と感じました。
何か見落としがあるようであれば、指摘していただけると助かります。

• • • • • • • • • • • • • • • • • • • • • • -

追記です。
やっぱりﾊﾞｰｼﾞｮﾝの食い違いによる事が原因でした。

まず、VBAのﾊﾞｰｼﾞｮﾝを確認します。

続いて参照設定を行います。

VBAが6.5だったので、"Microsoft APC 6.2 Object Library" にﾁｪｯｸを入れます。
VBAが7.Xの場合は、"Microsoft APC 7.1 Object Library" になるだろう
と思っています。(未確認)
恐らくﾒｼﾞｬｰﾊﾞｰｼﾞｮﾝさえ一致してれば良いのかな?

続いて、次のｺｰﾄﾞを用意しました。

'vba 現在開かれているVBﾌﾟﾛｼﾞｪｸﾄ数を表示
'事前に参照設定しておく必要あります

Sub GetVBE_Sample()
    Dim oVbe As Object: Set oVbe = GetVBE
    If oVbe Is Nothing Then Exit Sub
    
    MsgBox "現在開かれているﾌﾟﾛｼﾞｪｸﾄ数は" + CStr(oVbe.VBProjects.Count) + "個です"
End Sub

Private Function GetVBE() As Object ' VBE
    Set GetVBE = Nothing
    
    'APC取得
    On Error Resume Next
        Dim oApc As Apc: Set oApc = New Apc
    On Error GoTo 0
    
    If IsEmpty(oApc) Then
        MsgBox "参照設定が足りません"
        Exit Function
    End If
    
    'APCﾊﾞｰｼﾞｮﾝ取得
    Dim APCVerAry As Variant: APCVerAry = Split(oApc.APCVersion, ".")
    Dim APCVer&: APCVer = CLng(APCVerAry(0))
    
    'VBAﾊﾞｰｼﾞｮﾝ取得
    Dim VBAVer&: VBAVer = -1
    #If VBA6 Then
        VBAVer = 6
    #ElseIf VBA7 Then
        VBAVer = 7
    #Else
        MsgBox "VBAのﾊﾞｰｼﾞｮﾝが未対応です"
        Exit Function
    #End If
    
    'APCとVBAのﾊﾞｰｼﾞｮﾝﾁｪｯｸ
    If Not APCVer = VBAVer Then
        MsgBox "APCとVBAのﾊﾞｰｼﾞｮﾝが異なります" + vbNewLine + _
               "APCVer:" + oApc.APCVersion + vbNewLine + _
               "VBAVer:" + CStr(VBAVer) + ".X"
        Exit Function
    End If
    
    'VBE取得
    Set GetVBE = oApc.VBE
End Function

(ｺｰﾄﾞはﾊﾞｰｼﾞｮﾝの食い違いをﾁｪｯｸしていますが、実際に食い違う場合は
"参照設定が足りません" の所で引っかかると思います)

これを実行すると、こんな感じでVBｴﾃﾞｨﾀｰのTreeにぶら下がっている
ﾌﾟﾛｼﾞｪｸﾄ数が表示されればOKです。

VBEが取得できているので、後はExcel等のｻﾝﾌﾟﾙｺｰﾄﾞが流用できるような
気がしています。

念の為、CreateObjectを使った方法も考えて試してみました。
Excelの場合、ﾊﾞｰｼﾞｮﾝ指定してのｵﾌﾞｼﾞｪｸﾄの取得が出来ます。
Excelオブジェクト | Excel活用術

真似てこんなｺｰﾄﾞを作り実行しましたが

'vba
Sub MSAPC_Apc_Test2()
    Dim oApc 'As Apc
    Dim ApcVerName$, i&
    On Error Resume Next
        For i = 0 To 1000
            ApcVerName = "MSAPC.Apc." + CStr(i)
            Set oApc = CreateObject(ApcVerName)
            If Not IsEmpty(oApc) Then
                MsgBox "「" + ApcVerName + "」で取得出来ました"
                Exit For
            End If
        Next
    On Error GoTo 0
    MsgBox "該当なし"
End Sub

ﾀﾞﾒでした。　CreateObject("MSAPC.Apc") で取得できるのは
後にｲﾝｽﾄｰﾙされた方か、新しいﾊﾞｰｼﾞｮﾝの方になるような気がしています。
ﾚｼﾞｽﾄﾘを変更したりすれば、何とかなるのかも知れませんが
ここは素直に参照設定した方が無難な気がしました。

imihitoさん貴重な情報ありがとうございました。　ここまで出来れば
COEのｻﾝﾌﾟﾙｺｰﾄﾞも利用できそうですw

• • • • • • • • • • • • • • • • • • • • • • -

さらに追記です。
imihitoさんにさらなるｱﾄﾞﾊﾞｲｽを頂きました。

参照設定無しのCreateObjectﾊﾞｰｼﾞｮﾝです。(自宅のため未ﾃｽﾄ)

'vba 現在開かれているVBﾌﾟﾛｼﾞｪｸﾄ数を表示
'事前に参照設定する必要ありません

Sub GetVBE_Sample_CreateObject()
    Dim oVbe As Object: Set oVbe = GetVBE
    If oVbe Is Nothing Then Exit Sub
    
    MsgBox "現在開かれているﾌﾟﾛｼﾞｪｸﾄ数は" + CStr(oVbe.VBProjects.Count) + "個です"
End Sub

Private Function GetVBE() As Object ' VBE
    Set GetVBE = Nothing
    
    'VBAのﾊﾞｰｼﾞｮﾝﾁｪｯｸ
    Dim COMObjectName$
    #If VBA6 Then
        COMObjectName = "MSAPC.Apc.6.2"
    #ElseIf VBA7 Then
        COMObjectName = "MSAPC.Apc.7.1"
    #Else
        MsgBox "VBAのﾊﾞｰｼﾞｮﾝが未対応です"
        Exit Function
    #End If
    
    'APC取得
    Dim oApc As Object: Set oApc = Nothing
    On Error Resume Next
        Set oApc = CreateObject(COMObjectName)
    On Error GoTo 0
    
    'VBE取得
    If oApc Is Nothing Then
        MsgBox "MSAPC.Apcが取得できませんでした"
        Exit Function
    End If
    
    Set GetVBE = oApc.VBE
End Function

結局全て教わっちゃいました。