読み取り専用でﾌｧｲﾙを開く1

"読み取り専用でﾌｧｲﾙを開きたい" と御質問を頂きました。
過去に探した事が有り、"Unofficial CATIA User Forum" にも
記載したのですが･･･　生憎、ｿｰｽｺｰﾄﾞの管理が悪く　ｻﾝﾌﾟﾙが見つかりませんでした。

結論としては、CATIAのﾏｸﾛでﾄﾞｳｺｳでは無く、FileSystemObjectで
読み込むﾌｧｲﾙの属性を読み込み専用に変更した上で読み込み、
その後元に戻します。　要は読み込む瞬間だけ "読み込み専用"
としてしまえば良いだけでした。

ｻﾝﾌﾟﾙｺｰﾄﾞです。

'vba sample_FileOpen_ReadOnly_ver0.0.1
'読み取り専用でCATIAなﾌｧｲﾙを読み込む

Option Explicit
Private Const SelectionType = "*.CAT*" '"*.CATPart"
Private Const ReadOnly = 1& 'ﾌｧｲﾙ属性-読み取り専用

Sub CATMain()
    'ﾌｧｲﾙ選択
    Dim OpenFilePath As String
    Dim Msg As String: Msg = "読み取り専用で開くﾌｧｲﾙを選択してください"
    OpenFilePath = CATIA.FileSelectionBox(Msg, SelectionType, CatFileSelectionModeOpen)
    If OpenFilePath = vbNullString Then Exit Sub
    
    'ﾌｧｲﾙ属性取得
    Dim Original As Long: Original = GetAttributes(OpenFilePath)
    
    '属性ﾁｪｯｸし必要なら変更
    If Not (Original And ReadOnly = ReadOnly) Then
        Call SetAttributes(OpenFilePath, ReadOnly)
    End If
    
    '読み込み
    Call CATIA.Documents.Open(OpenFilePath)
    
    '属性を変更していたら元に戻す
    If Not (Original And ReadOnly = ReadOnly) Then
        Call SetAttributes(OpenFilePath, Original)
    End If
End Sub

'FileSystemObject
Private Function GetFSO() As Object
    Set GetFSO = CreateObject("Scripting.FileSystemObject")
End Function

'ﾌｧｲﾙ属性設定
Private Sub SetAttributes(ByVal Path As String, ByVal Value As Long)
    Dim Fso As Object: Set Fso = GetFSO
    Fso.GetFile(Path).Attributes = Value
End Sub

'ﾌｧｲﾙ属性取得
Private Function GetAttributes(ByVal Path As String) As Long
    Dim Fso As Object: Set Fso = GetFSO
    GetAttributes = Fso.GetFile(Path).Attributes
End Function

FileSelectionBoxを利用してﾌｧｲﾙを選択させていますが、単に開きたい
ﾌｧｲﾙのﾊﾟｽを指定してもOKです。

FileSelectionBoxについては、第二引数の表示させるﾌｧｲﾙの拡張子の
指定なのですが複数の拡張子を指定できなさそうな為、苦し紛れな
ﾜｲﾙﾄﾞｶｰﾄﾞを利用しています。
(catvbaやCATScript等、本来表示させるべきではないものまで表示されます)

実際にﾏｸﾛを利用して開いた感じはこちらです。

CATIA上では "読み込み専用" となっていますが、実際のﾌｧｲﾙのﾌﾟﾛﾊﾟﾃｨ(右下)は
"読み込み専用" となっていません。

ﾌｧｲﾙは例の宿題です。　忙しい上に、機械が空かなかったり･･･(言い訳)

※涙が出るほどの初歩的な誤記を修正しました･･･。