ﾌｧｲﾙ間ﾘﾝｸの取得6

こちらの続きです。
ﾌｧｲﾙ間ﾘﾝｸの取得5 - C#ATIA

ようやく、妥協しまくりですが出来上がりました。

ﾏｸﾛでの利用が目的な為、本来DLLﾌｧｲﾙとして提供すべきだとは
思うのですが、C#作成のDLLをVBAで利用する為にはﾚｼﾞｽﾄﾘに
DLLを登録する必要がある為、実行ﾌｧｲﾙ(EXE)としました。

実行ﾌｧｲﾙ、ｿｰｽｺｰﾄﾞ(C#)、ｻﾝﾌﾟﾙﾏｸﾛ(VBA)等は、こちらの
ｻｲﾄにUPしてます。
GrabCAD - CAD library
・exe_file ： ﾘﾝｸ情報を取得するﾌﾟﾛｸﾞﾗﾑ（日本語・英語のみ）
・cs_Source ： ｿｰｽｺｰﾄﾞ（C#）　GNU General Public License
・vba_SupportClass ： VBA用ｻﾎﾟｰﾄｸﾗｽﾓｼﾞｭｰﾙ
・vba_sample ： VBA用ｻﾝﾌﾟﾙﾏｸﾛ
・hoge.CATPart　＆　piyo.CATDrawing ： ｻﾝﾌﾟﾙCATIAﾃﾞｰﾀ(R2012)
実行ﾌｧｲﾙ名は「catv5_GetLinkReport.exe」です。
又、ｿｰｽｺｰﾄﾞについては、大本さんがGNUﾗｲｾﾝｽを表記している為、
同様にGNUﾗｲｾﾝｽとさせてください。

利用する際には、VBAから外部ﾌﾟﾛｸﾞﾗﾑとして実行します。
処理終了後は、ｱｸﾃｨﾌﾞなﾌｧｲﾙと同一ﾌｫﾙﾀﾞ内に
「ｱｸﾃｨﾌﾞﾌｧｲﾙ名 + "_LinkReport.csv"」と言うCSVﾌｫｰﾏｯﾄのﾌｧｲﾙが
作成される為、このﾌｧｲﾙを読み込む事でﾘﾝｸ情報を取得できます。

作成されるCSVﾌｧｲﾙは、このような状態です。

"ﾄﾞｷｭﾒﾝﾄのﾘﾝｸ" の "ﾘﾝｸ" ﾀﾌﾞ時の情報で、"元ｴﾚﾒﾝﾄ""宛先ｴﾚﾒﾝﾄ"・・・
の順番となっています。

実際にこのﾌﾟﾛｸﾞﾗﾑを利用したｻﾝﾌﾟﾙです。

'VBA ﾘﾝｸ情報取得ｻﾎﾟｰﾄｸﾗｽ
'GetLinkReportSupport.cls
Option Explicit

'-----設定-----
'catv5_LinkReport.exeﾌｧｲﾙのﾌﾙﾊﾟｽ
Const GetLinkReportExePath = "C:\temp\library\catv5_GetLinkReport.exe"
'--------------

'こちらは変更しないで下さい
Const FileNameFooter = "_LinkReport.csv"
Dim FSO As Object

Private Sub Class_Initialize()
    Set FSO = CreateObject("Scripting.FileSystemObject")
End Sub

Private Sub Class_Terminate()
    Set FSO = Nothing
End Sub

'ﾘﾝｸ情報取得
Public Function GetLinkReport() As Variant
    'GetLinkReportExePathﾊﾟｽﾁｪｯｸ
    If Not FSO.FileExists(GetLinkReportExePath) Then
        MsgBox "GetLinkReportExePathの設定が間違っています"
        GetLinkReport = Array()
        Exit Function
    End If
    
    'GetLinkReportExe実行
    Dim WshShell As Object: Set WshShell = CreateObject("WScript.Shell")
    Call WshShell.Run(GetLinkReportExePath + " OFF", 0, True)
    Set WshShell = Nothing
    'Call Shell(GetLinkReportExePath + " OFF", vbNormalNoFocus) 'これは確実だが遅い
    
    
    'LinkReportﾌｧｲﾙ名取得
    Dim ReportFilePath As String
    ReportFilePath = GetReportFilePath(CATIA.ActiveDocument.FullName)
    
    'LinkReportﾌｧｲﾙ有無ﾁｪｯｸ
    If Not FSO.FileExists(ReportFilePath) Then
        GetLinkReport = Array()
        Exit Function
    End If
    
    'LinkReportﾌｧｲﾙ取得
    GetLinkReport = ReadFile(ReportFilePath)
End Function

'LinkReportﾌｧｲﾙ名取得
Private Function GetReportFilePath(ByVal Path) As String
    GetReportFilePath = FSO.GetParentFolderName(Path) + "\" + FSO.GetBaseName(Path) + FileNameFooter
End Function

'ﾌｧｲﾙを読み込み　return-ｼﾞｬｸﾞ配列化
Private Function ReadFile(ByVal Path) As Variant
    If FSO.GetFile(Path).Size < 1 Then
        ReadFile = Array()
        Exit Function
    End If

    Dim TxtFile As Object: Set TxtFile = FSO.OpenTextFile(Path)
    Dim txt As String: txt = TxtFile.ReadAll
    Dim arytxt As Variant: arytxt = Split(txt, vbNewLine)
    
    Dim i As Integer
    Dim Jagary() As Variant: ReDim Jagary(UBound(arytxt))
    For i = 0 To UBound(arytxt)
        Jagary(i) = Split(arytxt(i), ",")
    Next
    
    ReadFile = Jagary
    Set TxtFile = Nothing
End Function

外部ﾌﾟﾛｸﾞﾗﾑを実行し、作成されたCSVﾌｧｲﾙを読み込む為のｻﾎﾟｰﾄｸﾗｽﾓｼﾞｭｰﾙです。
GetLinkReportExePath定数には、実際に利用する際のﾌﾙﾊﾟｽに直してください。
必ずこのｸﾗｽを使用する必要は無いのですが、説明を簡略化したかったので・・・。

Call WshShell.Run(GetLinkReportExePath + " OFF", 0, True)

この部分で、設定されたﾊﾟｽを元に外部ﾌﾟﾛｸﾞﾗﾑを実行させていますが、
実行する際のｵﾌﾟｼｮﾝとして " OFF" を付けています。
このｵﾌﾟｼｮﾝを付ける事で、VBAﾏｸﾛからの実行時の面倒なﾒｯｾｰｼﾞの一部の
表示を止めています。
(ｵﾌﾟｼｮﾝ無しでは、CSVﾌｧｲﾙの上書きの確認と処理の終了のﾒｯｾｰｼﾞが出ます)

続いて、このｻﾎﾟｰﾄｸﾗｽを利用したｻﾝﾌﾟﾙです。
PartﾌｧｲﾙからﾘﾝｸしているDrawﾌｧｲﾙをｱｸﾃｨﾌﾞにし、Viewをｸﾘｯｸする事で
ﾘﾝｸ元の "宛先ｴﾚﾒﾝﾄ" をMsgBoxで表示します。

'VBA Draw-宛先ｴﾚﾒﾝﾄ取得ｻﾝﾌﾟﾙ
'GetLinkSample.bas
Option Explicit

Dim LinkReport As Variant '取得したﾘﾝｸ情報

Sub CatMain()
    'DrawDocﾁｪｯｸ
    If Not TypeName(CATIA.ActiveDocument) = "DrawingDocument" Then
        MsgBox "CATDrawingﾌｧｲﾙをｱｸﾃｨﾌﾞにして下さい!"
        Exit Sub
    End If
    
    'ﾘﾝｸ情報の取得
    LinkReport = GetLinkReport
    If UBound(LinkReport) < 0 Then
        MsgBox "ﾘﾝｸ情報が取得できませんでした"
        Exit Sub
    End If
    
    'Viewの選択
    Dim ActSel As Variant: Set ActSel = CATIA.ActiveDocument.Selection
    Dim SelFilter As Variant: SelFilter = Array("DrawingView")
    Dim SelMsg As String: SelMsg = "ﾘﾝｸ元を調べるﾋﾞｭｰを選択して下さい : [Esc]=ｷｬﾝｾﾙ"
    Do
        ActSel.Clear
        Select Case ActSel.SelectElement2(SelFilter, SelMsg, False)
            Case "Cancel", "Undo", "Redo"
                Exit Do
        End Select
        Call ShowMsg(FindLinkData(ActSel.Item(1).value.name))
    Loop
    ActSel.Clear
End Sub

'ﾘﾝｸ情報の取得
Private Function GetLinkReport() As Variant
    Dim GetLinkClass As GetLinkReportSupport: Set GetLinkClass = New GetLinkReportSupport
    GetLinkReport = GetLinkClass.GetLinkReport
    Set GetLinkClass = Nothing
End Function

'ﾘﾝｸ情報から検索
Private Function FindLinkData(ByVal ViewName As String) As String
    Dim lr As Variant
    Dim Result() As String: ReDim Result(UBound(LinkReport))
    Dim HitCount As Integer: HitCount = -1
    For Each lr In LinkReport
        If InStr(lr(0), ViewName) Then
            HitCount = HitCount + 1
            Result(HitCount) = lr(1)
        End If
    Next
    If HitCount < 0 Then Exit Function
    ReDim Preserve Result(HitCount)
    FindLinkData = Join(Result, vbNewLine)
End Function

'ﾘﾝｸﾒｯｾｰｼﾞ表示
Private Sub ShowMsg(ByVal Msg As String)
    Msg = IIf(Len(Msg) < 1, _
                "ﾘﾝｸを持っていません!", _
                "ﾘﾝｸ元は" + vbNewLine + Msg + vbNewLine + "です")
    MsgBox Msg
End Sub

GetLinkReport関数で先程のｻﾎﾟｰﾄｸﾗｽを経由して、ﾘﾝｸ情報を取得しています。
戻り値はｼﾞｬｸﾞ配列となっており、FindLinkData関数で選択したView名と
照らし合わせて、ﾘﾝｸ元の "宛先ｴﾚﾒﾝﾄ" の情報を抜き出しています。

説明不足感たっぷりですが、このような感じです。
お気付きの方もいると思うのですが、実行ファイルのため
「ﾏｸﾛわかんない」
と言う方も、ﾘﾝｸ情報を取得したいﾌｧｲﾙをｱｸﾃｨﾌﾞにし、ﾏｳｽでﾀﾞﾌﾞﾙｸﾘｯｸ
してもらうと、CSVﾌｧｲﾙ自体は作成されます。

ﾃｽﾄ不十分な上、英語表記がかなり疑わしいので指摘していただけると
助かります。（ｺｰﾄﾞ的におかしい部分の指摘していただけるとありがたいです）

最後に参考させてもらったｻｲﾄです。
○Digital Photos
Catia V5 Get Links
このｺｰﾄﾞが無ければ、作成出来ませんでした。
色々と学ぶべき部分がありました。

○MT-Soft
リストビュー文字列取得−ＶＢパーツ
VBでのﾘｽﾄﾋﾞｭｰの文字列取得のｺｰﾄﾞを、参考にさせてもらいました。
VBは型変換を自動で行ってしまう部分があり、そのままC#化できません
でしたが、かなり助かりました。

○DOBON.NET
C#のWindowsAPIでツリーのテキストが取得できません: DOBON.NETプログラミング掲示板過去ログ
C#でのﾂﾘｰﾋﾞｭｰの文字列取得のｺｰﾄﾞを、参考にさせてもらいました。
ﾂﾘｰﾋﾞｭｰなのでちょっと違うのですが、C#でのWinAPIの利用の仕方は
かなり参考になりました。

○ちょくとのページ
ウィンドウメッセージリスト
WinAPIの定数関連を参考にさせてもらいました。
何のｻｲﾄかと思ったら、HSP関連のｻｲﾄなんですね。
HSPすごいなぁ。