外部のﾏｸﾛを実行する2

こちらの続きです。
外部のﾏｸﾛを実行する1 - C#ATIA

前回はCATVBAからCATScriptを呼び出す処理でしたが、
今度はCATVBAからCATVBAを呼び出します。

まず、「C:\temp」ﾌｫﾙﾀﾞにVBAﾌﾟﾛｼﾞｪｸﾄのﾗｲﾌﾞﾗﾘ
「Outside_Macro_Test1」を作りﾓｼﾞｭｰﾙ名「AddHBody」
のﾓｼﾞｭｰﾙを作りました。

「AddHBody」の中には、前回CATScriptと同様です。

'vba
Sub CATMain()
    Dim partDocument1 As PartDocument
    Set partDocument1 = CATIA.ActiveDocument
    
    Dim part1 As Part
    Set part1 = partDocument1.Part
    
    Dim hybridBodies1 As HybridBodies
    Set hybridBodies1 = part1.HybridBodies
    
    For I = 1 To 5
        Call hybridBodies1.Add
    Next
    part1.Update
End Sub

次に同一ﾌﾟﾛｼﾞｪｸﾄ内にﾓｼﾞｭｰﾙ名「Call_Inside」の
ﾓｼﾞｭｰﾙを作りました。

こちらのｺｰﾄﾞも、前回のVBAのｺｰﾄﾞと同等なのですが、
上記の「AddHBody」ﾓｼﾞｭｰﾙのCATMainを呼び出すように
しました。

'vba
Sub CATMain()
    Call AddHBody.CATMain '←呼び出し
    
    Dim Doc As PartDocument
    Set Doc = CATIA.ActiveDocument
    
    Dim HBs As HybridBodies
    Set HBs = Doc.Part.HybridBodies
    
    Dim I As Long
    For I = 1 To HBs.Count
        HBs.Item(I).Name = "Hoge" + CStr(I)
    Next
    Doc.Part.Update
End Sub

まぁ、特別な事は無いです。　ｽｺｰﾌﾟの問題さえｸﾘｱしていれば
呼び出す際は「ﾓｼﾞｭｰﾙ名 . 関数名」にすれば良いだけなので。

結果はこちらです。

正しく処理できました。

問題は、別ﾌﾟﾛｼﾞｪｸﾄから任意の関数を呼び出す場合です。
まず別ﾌﾟﾛｼﾞｪｸﾄを作ります。「C:\temp」ﾌｫﾙﾀﾞにVBAﾌﾟﾛｼﾞｪｸﾄの
ﾗｲﾌﾞﾗﾘ「Outside_Macro_Test2」を作りﾓｼﾞｭｰﾙ名「Call_Outside」
のﾓｼﾞｭｰﾙを作りました。

どの様にして呼び出せばよいのか？　よくわからなかったので、
ExcelVBAを参考にしてみます。
Office TANAKA - Excel VBA Tips[他ブックのマクロを実行する]
(OfficeTANAKAさん　いつもお世話になっちゃうなぁ)

「Call_Outside」の中身はこんなｺｰﾄﾞにしてみました。

'vba
Sub CATMain()
    Application.Run "Outside_Macro_Test1!AddHBody.CATMain"
    
    Dim Doc As PartDocument
    Set Doc = CATIA.ActiveDocument
    
    Dim HBs As HybridBodies
    Set HBs = Doc.Part.HybridBodies
    
    Dim I As Long
    For I = 1 To HBs.Count
        HBs.Item(I).Name = "Hoge" + CStr(I)
    Next
    Doc.Part.Update
End Sub

実行すると

余裕でﾀﾞﾒなんですよ。そもそもCATIAのApplicationｸﾗｽには
Run関数なんて無いんです。

"R" で始まるのは "RefreshDisplay" しか無いんです。

そこで登場するのが、前回のExecuteScript関数なんです。
で、「Call_Outside」を直してみました。

'vba
Sub CATMain()
    Dim VBAProjectPath As String 'ﾌﾟﾛｼﾞｪｸﾄまでのﾊﾟｽ
    VBAProjectPath = "C:\temp\Outside_Macro_Test1.catvba"
    
    Dim LibraryType As CatScriptLibraryType 'ﾗｲﾌﾞﾗﾘの種類
    LibraryType = catScriptLibraryTypeVBAProject
    
    Dim ScriptName As String 'ﾓｼﾞｭｰﾙ名
    ScriptName = "AddHBody"
    
    Dim FunctionName As String '関数名
    FunctionName = "CATMain"
    
    Dim Params() As Variant '引数 空でも渡す
    
    Dim SS As Variant 'SystemService
    Set SS = CATIA.SystemService
    
    '外部呼出し
    Call SS.ExecuteScript(VBAProjectPath, LibraryType, _
                          ScriptName, FunctionName, Params)
                          

    Dim Doc As PartDocument
    Set Doc = CATIA.ActiveDocument
    
    Dim HBs As HybridBodies
    Set HBs = Doc.Part.HybridBodies
    
    Dim I As Long
    For I = 1 To HBs.Count
        HBs.Item(I).Name = "Hoge" + CStr(I)
    Next
    Doc.Part.Update
End Sub

前回はｻｻｯとやってしましましたが、ｺﾒﾝﾄ付けました。
Params()に関しては試していないのですが、不要でも空の
Variant型配列は渡す必要があるようです。
実行結果はこちら。

正しく処理できました。　ん！VBEのProjectTreeを見ると

呼び出された側のProjectが増えてる・・・。
何これ？　怖いんだけど・・・。

何度も試したのですが、これ以上は増えませんでした。
ﾏｸﾛﾗｲﾌﾞﾗﾘ-見ると増えたわけではありませんでした。

VBEを消しても直らず、CATIAを落とせば元に戻りました。
表示上の問題かなぁ。

よく考えると、ExecuteScript関数は、"ﾌﾟﾛｼﾞｪｸﾄまでのﾊﾟｽ"
"ﾗｲﾌﾞﾗﾘの種類" "ﾓｼﾞｭｰﾙ名" "関数名" と何から何まで指定して
います。試しに「Outside_Macro_Test1」ﾌﾟﾛｼﾞｪｸﾄ自体をﾗｲﾌﾞﾗﾘ
から外してしまいます。　こんな感じです。

この状態で、先程のﾏｸﾛを実行すると

正しく実行できました。　ExecuteScript関数はﾗｲﾌﾞﾗﾘとして
取り込んでいないﾌﾟﾛｼﾞｪｸﾄのﾏｸﾛの呼び出しも可能のようです。
但し、実行後はﾌﾟﾛｼﾞｪｸﾄを取り込んだ状態になってしまいます。
先程の同一ﾌﾟﾛｼﾞｪｸﾄが2つ表示された状態になるのは、この事が
原因なのかも知れません。