外部のﾏｸﾛを実行する1

VBAから外部のﾌﾟﾛｸﾞﾗﾑを起動して、処理したいことが偶にあります。
Excelであればこんな感じです。
他アプリを起動する：Excel VBA｜即効テクニック｜Excel VBAを学ぶならmoug

過去にﾌﾞﾛｸﾞに記載したものでも、実際にWscript.Shellを使いました。
（GetLinkReportSupport.clsのGetLinkReport関数内です）
ﾌｧｲﾙ間ﾘﾝｸの取得6 - C#ATIA

外部のﾌﾟﾛｸﾞﾗﾑを利用する場合、ちょっとした問題があります。
例として、あまり現実味がないのですがCATVBAからCATScriptを
呼び出す処理をしてみます。

まず、呼び出されるCATScriptです。
これを「C:\temp」ﾌｫﾙﾀﾞに「AddHBody.CATScript」として
作成しておきます。

'CATScript
'AddHBody.CATScript
Sub CATMain()
    Dim partDocument1 As PartDocument
    Set partDocument1 = CATIA.ActiveDocument
    
    Dim part1 As Part
    Set part1 = partDocument1.Part
    
    Dim hybridBodies1 As HybridBodies
    Set hybridBodies1 = part1.HybridBodies
    
    For i = 1 To 5
        Call hybridBodies1.Add
    Next
    part1.Update
End Sub

内容はｱｸﾃｨﾌﾞなPartﾌｧｲﾙに、形状ｾｯﾄを5個作るだけです。

続いて、呼び出し側のVBAのｺｰﾄﾞです。

'vba
Sub Call_By_Shell()
    Dim CATScriptPath As String
    CATScriptPath = "C:\temp\AddHBody.CATScript"
    
    '外部呼出し
    Call CreateObject("Wscript.Shell").Run(CATScriptPath, 5)
    
    '形状ｾｯﾄ名ﾘﾈｰﾑ
    Dim Doc As PartDocument
    Set Doc = CATIA.ActiveDocument
    
    Dim HBs As HybridBodies
    Set HBs = Doc.Part.HybridBodies
    Dim I As Long
    For I = 1 To HBs.Count
        HBs.Item(I).Name = "Hoge" + CStr(I)
    Next
    Doc.Part.Update
End Sub

内容は先程のCATScriptを実行して、出来上がった形状ｾｯﾄ名を
全て変更します。　もちろん2つに分ける意味は全く無いのですが。

Partﾌｧｲﾙを新規に作成し、VBAを実行した結果がこちら。
f:id:kandennti:20160414173832p:plain

形状ｾｯﾄは作成されているのですが、ﾘﾈｰﾑされていません。
再度実行した結果がこちら。
f:id:kandennti:20160414173850p:plain

最初に実行した分はﾘﾈｰﾑできているのですが、2回目に作成
された分はやはりﾘﾈｰﾑされていません。
CATScriptを呼び出すのですが、処理終了とは無関係でVBAが
突っ走って処理しているんです。

最初のﾘﾝｸにも記載されていますが、公式なものを見ると
Run メソッド

Wscript.Shellのrun関数の第三引数を "True" にすると
"呼び出された処理が終わるまで、呼び出し側の処理が止まる"
と記載されているみたいです。

なので、VBA側のｺｰﾄﾞをこのように修正しました。

'vba
Sub Call_By_Shell()
    ・・・
    
    '外部呼出し
    Call CreateObject("Wscript.Shell").Run(CATScriptPath, 5, True)
    
    ・・・

実行すると
f:id:kandennti:20160414173902p:plain

ｴﾗｰがVBA側で出ちゃうんです。　形状ｾｯﾄは出来上がるので
CATScriptは呼び出されるのですが、処理終了を拾えないんです。
恐らくCATScript側が処理終了のｻｲﾝを発しないんだろうと思います。
Wscript.Shellを利用した方法だと、ちょっとした工夫必要なんです。

CATIAのﾏｸﾛには外部のﾌﾟﾛｸﾞﾗﾑを実行させる関数が、実装されています。
存在は前から知っていたのですが、どうしてもｴﾗｰになり利用できなかった
のですが、最近になってようやくわかりました。
以前紹介したTech-Eckeのｻｲﾄの
「CATScript/VBS」-「Externe Scripts und Anwendungen」
にｻﾝﾌﾟﾙがあります。
Tech-Ecke

参考にしてｺｰﾄﾞを直しました。

'vba
Sub Call_By_ExecuteScript()
    Dim CATScriptPath As String
    CATScriptPath = "C:\temp"
    
    Dim LibraryType As CatScriptLibraryType
    LibraryType = catScriptLibraryTypeDirectory
    
    Dim ScriptName As String
    ScriptName = "AddHBody.CATScript"
    
    Dim FunctionName As String
    FunctionName = "CATMain"
    
    Dim Params() As Variant
    
    '外部呼出し
     Call CATIA.SystemService.ExecuteScript(CATScriptPath, _
                                           LibraryType, _
                                           ScriptName, _
                                           FunctionName, _
                                           Params)

    '形状ｾｯﾄ名ﾘﾈｰﾑ
    Dim Doc As PartDocument
    Set Doc = CATIA.ActiveDocument
    
    Dim HBs As HybridBodies
    Set HBs = Doc.Part.HybridBodies
    Dim I As Long
    For I = 1 To HBs.Count
        HBs.Item(I).Name = "Hoge" + CStr(I)
    Next
    Doc.Part.Update
End Sub

実行してみると
f:id:kandennti:20160414173916p:plain
ｴﾗｰなんです。　どうしてもﾀﾞﾒなんです。
それで、ExecuteScript関数は見つけなかった事にしていたんですw

それが最近になってこんな感じに修正してみました。

    ・・・

    Dim SS As Variant 'SystemService
    Set SS = CATIA.SystemService
    
    '外部呼出し
    Call SS.ExecuteScript(CATScriptPath, LibraryType, _
                          ScriptName, FunctionName, Params)

    ・・・