ﾌﾟﾛｼﾞｪｸﾄの情報部分をｲﾝﾎﾟｰﾄ・ｴｸｽﾎﾟｰﾄする2

こちらの続きです。
ﾌﾟﾛｼﾞｪｸﾄの情報部分をｲﾝﾎﾟｰﾄ・ｴｸｽﾎﾟｰﾄする1 - C#ATIA

先日作ったｴｸｽﾎﾟｰﾄしたﾌｧｲﾙをｲﾝﾎﾟｰﾄする為のﾏｸﾛです。

//pm2018 macro
//ProjInfoIpt.mac ver0.0.1
//PMillﾌﾟﾛｼﾞｪｸﾄ情報部のｲﾝﾎﾟｰﾄ
//--------------------------------------------------------------------
//ver0.0.1-完成
//--------------------------------------------------------------------

function main() {
	//ﾌｧｲﾙの選択
	string path = ''
	call SelFile($path)
	
	//存在ﾁｪｯｸ
	string msg = ''
	if not file_exists($path) {
		$msg = '指定ﾌｧｲﾙが存在しません!!'
		message warn $msg
		macro abort
	}
	
	//読み込み
	string list txts = {}
	call ReadFile($path, $txts) 
	string list infos = tokens($txts[0], ',')
	if size($infos) < 3 {
		$msg = '指定したﾌｧｲﾙが不正です!!'
		message warn $msg
		macro abort
	}
	
	//確認
	$msg = ''
	$msg = $msg + '顧客名 : ' +  $infos[0] + crlf
	$msg = $msg + 'ﾊﾟｰﾂ名 : ' +  $infos[1] + crlf
	$msg = $msg + '注文番号 : ' +  $infos[2] + crlf
	$msg = $msg + 'をｲﾝﾎﾟｰﾄしますか?'
	bool yn  = 0
	$yn = QUERY $msg
	if not $yn {
		macro abort
	}
	
	//ｲﾝﾎﾟｰﾄ
	string list prms ={'Customer', 'PartName', 'OrderNumber'}
	string cmd = ''
	foreach i in {0,1,2} {
		$cmd = 'EDIT PAR "project.' + $prms[i] + '" "' +infos[i] +'"'
		docommand $cmd
	}
	message info  'Done'		
}

///////////////
//ﾌｧｲﾙの選択
function SelFile(output string out) {
	string title = 'PMillﾌﾟﾛｼﾞｪｸﾄｺﾒﾝﾄ'
	string filter = 'PMillﾌﾟﾛｼﾞｪｸﾄｺﾒﾝﾄ(.PmCmt)|*.PmCmt|'
	
	string defpath = ''
	call GetParentDir($defpath)
	$out = fileselect $title $filter $defpath
	if length($out) < 1 {
		macro abort 
	}
}

//ﾌﾟﾛｼﾞｪｸﾄの一個上のﾊﾟｽ取得 何か方法あるのかな？
function GetParentDir(output string out) {
	string s = project_pathname(0)
	int p1 = -1
	int p2 = 0
	while ($p2 > -1) {
		$p1 = position($s, '/', $p2)
		if $p1 < 0 {
			break
		}
		$p2 = $p1 + 1
	}
	$out= substring($s, 0, $p2 -1)
}

//ﾌｧｲﾙ読み込み
function ReadFile(string path, output string list out) {
	file open $path for read as f
	file read $out from f
	file close f
}

案の定、最低限のﾁｪｯｸしかしていません。